/****************** Jordan Perr 2010 ******************/

// Variables to mess with

final color bgColor = #171717;     // Color of background
final color atColor = #DDAABB;     // Color of attractor
final boolean fadeout = true;      // Fade the attractor?
final color fadeColor = #443344;   // Color of fade

final int framerate = 400;         // Framerate
final int LIMIT = 9001;            // Itteration to stop at
final float SCALE = 5;             // Rendering zoom factor

final double dt = 0.01;             // dt
final double init_x = 20;           // xcor of start
final double init_y = 1;            // ycor of start
final double init_z = 0;            // zcor of start

final double s = 10;               // "sigma" term
final double b = 8/2;              // "beta" term
final double r = 28;               // "rho" term


// Attractor generation and drawing

//import processing.opengl.*;

double attractor[][];
int numPoints = 0;
float oldMouseX = 0;

void setup()
{
  attractor = new double[LIMIT][3];
  attractor[0][0] = init_x;
  attractor[0][1] = init_y;
  attractor[0][2] = init_z;
  size(800,600,P3D);
  //hint(ENABLE_OPENGL_4X_SMOOTH);
  background(bgColor);
  frameRate(framerate);
}

void render()
{
  translate(width/2, height/2);
  rotateY(mouseX*4*PI/(float)width);
  //rotateX(-mouseY*PI/(float)width - 1.5*PI);
  stroke(atColor);

  if (oldMouseX != mouseX || fadeout){
    background(bgColor);
    for (int i = 1; i<numPoints; i+=1)
    {
      if(fadeout)
        stroke(lerpColor(fadeColor, atColor, i/(float)numPoints));
        
      line((float)attractor[i-1][0] * SCALE,
           (float)attractor[i-1][1] * SCALE,
           (float)attractor[i-1][2] * SCALE,
           (float)attractor[i][0]   * SCALE,
           (float)attractor[i][1]   * SCALE,
           (float)attractor[i][2]   * SCALE);
    }
  } else {
    line((float)attractor[numPoints-1][0] * SCALE,
         (float)attractor[numPoints-1][1] * SCALE,
         (float)attractor[numPoints-1][2] * SCALE,
         (float)attractor[numPoints-2][0] * SCALE,
         (float)attractor[numPoints-2][1] * SCALE,
         (float)attractor[numPoints-2][2] * SCALE);
  }
  oldMouseX = mouseX;
}

void nextPoint()
{
  numPoints++;
  attractor[numPoints][0] = attractor[numPoints-1][0] + (s * (attractor[numPoints-1][1] - attractor[numPoints-1][0])) * dt;
  attractor[numPoints][1] = attractor[numPoints-1][1] + (r*attractor[numPoints-1][0] - attractor[numPoints-1][1] - attractor[numPoints-1][0]*attractor[numPoints-1][2]) * dt;
  attractor[numPoints][2] = attractor[numPoints-1][2] + (attractor[numPoints-1][0]*attractor[numPoints-1][1] - b*attractor[numPoints-1][2]) * dt;
}

void draw()
{

 if (numPoints < LIMIT-1)
  nextPoint();
 
 if (numPoints >= 2)
  render();

}